LibJF/build.gradle

apply from: "https://jfmods.gitlab.io/scripts/jfmod.gradle"

allprojects {
    sourceSets {
        testmod {
            compileClasspath += main.compileClasspath
            runtimeClasspath += main.runtimeClasspath
        }
    }

    loom {
        runs {
            testmodClient {
                client()
                ideConfigGenerated project.rootProject == project
                name = "Testmod Client"
                source sourceSets.testmod
            }
            testmodServer {
                server()
                ideConfigGenerated project.rootProject == project
                name = "Testmod Server"
                source sourceSets.testmod
            }
        }

        runConfigs.configureEach {
            vmArgs "-Dfabric.debug.classPathIsolationBypassClasses=io/gitlab/jfronny/libjf"
        }
    }

    dependencies {
        modImplementation("com.terraformersmc:modmenu:3.1.0")
        modRuntimeOnly("net.fabricmc.fabric-api:fabric-api:$project.fabric_version")
        modImplementation("io.gitlab.jfronny:commons:$project.commons_version")
        modImplementation("io.gitlab.jfronny:commons-gson:$project.commons_version")
        modImplementation("io.gitlab.jfronny:commons-slf4j:$rootProject.commons_version")
    }
}

subprojects {
    dependencies {
        testmodImplementation sourceSets.main.output
    }
}

sourceSets {
    testmod
}