LibJF/build.gradle

apply from: "https://jfmods.gitlab.io/scripts/jfmod.gradle"

allprojects {
    sourceSets {
        testmod {
            compileClasspath += main.compileClasspath
            runtimeClasspath += main.runtimeClasspath
        }
    }

    loom {
        runs {
            testmodClient {
                client()
                ideConfigGenerated project.rootProject == project
                name = "Testmod Client"
                source sourceSets.testmod
            }
            testmodServer {
                server()
                ideConfigGenerated project.rootProject == project
                name = "Testmod Server"
                source sourceSets.testmod
            }
        }
    }

    dependencies {
        modImplementation("com.terraformersmc:modmenu:3.1.0")
        modRuntimeOnly("net.fabricmc.fabric-api:fabric-api:$project.fabric_version")
        modImplementation('io.gitlab.jfronny:gson:2.9.0.2022.4.2.19.45.43')
    }
}

subprojects {
    dependencies {
        testmodImplementation sourceSets.main.output
    }
}

sourceSets {
    testmod
}