var cl = Calendar.instance
var day = "${cl.get(cl.YEAR)}.${cl.get(cl.MONTH) + 1}.${cl.get(cl.DATE)}"
var time = "${cl.get(cl.HOUR_OF_DAY)}-${cl.get(cl.MINUTE)}-${cl.get(cl.SECOND)}"

allprojects {
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'

    version = "$day+$time"

    repositories {
        mavenCentral()
        maven {
            url 'https://gitlab.com/api/v4/projects/35030495/packages/maven'
        }
    }

    dependencies {
        compileOnly 'org.jetbrains:annotations:23.0.0'

        testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.2'
        testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.2'
    }

    test {
        useJUnitPlatform()
    }

    java {
        withSourcesJar()
    }

    publishing {
        def ENV = System.getenv()
        if (project.hasProperty("maven")) {
            repositories.maven {
                url = project.getProperty("maven")
                name = "dynamic"

                credentials(HttpHeaderCredentials) {
                    name = "Job-Token"
                    value = ENV.CI_JOB_TOKEN
                }
                authentication {
                    header(HttpHeaderAuthentication)
                }
            }
        }
        repositories.mavenLocal()
    }
}

subprojects {
    dependencies {
        implementation project(':')

        testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.2'
        testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.2'
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            groupId = 'io.gitlab.jfronny'
            artifactId = 'commons'

            from components.java
        }
    }
}