plugins {
    id 'java-library'
    id 'maven-publish'
    id 'com.github.johnrengelman.shadow' version '7.1.2'
}

repositories {
    mavenCentral()
    maven {
        url 'https://gitlab.com/api/v4/projects/35030495/packages/maven'
    }
}

dependencies {
    shadow implementation('io.gitlab.jfronny:gson:+')

    implementation project(':')

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.2'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.2'
}

shadowJar {
    configurations = [ project.configurations.shadow ]
}

test {
    useJUnitPlatform()
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            groupId = 'io.gitlab.jfronny'
            artifactId = 'commons-gson'
            var cl = Calendar.instance
            var day = "${cl.get(cl.YEAR)}.${cl.get(cl.MONTH) + 1}.${cl.get(cl.DATE)}"
            var time = "${cl.get(cl.HOUR_OF_DAY)}.${cl.get(cl.MINUTE)}.${cl.get(cl.SECOND)}"
            version = "${rootProject.versionPrefix}.$day.$time"

            project.shadow.component(it)
        }
    }

    def ENV = System.getenv()
    if (project.hasProperty("maven")) {
        repositories.maven {
            url = project.getProperty("maven")
            name = "dynamic"

            credentials(HttpHeaderCredentials) {
                name = "Job-Token"
                value = ENV.CI_JOB_TOKEN
            }
            authentication {
                header(HttpHeaderAuthentication)
            }
        }
    }
    repositories.mavenLocal()
}