import io.gitlab.jfronny.convention.ext.*
import io.gitlab.jfronny.lom.ext.*

plugins {
    id("jfmod")
    id("com.modrinth.minotaur")
}

val readmeFile = file("README.md")

modrinth {
    token.set(System.getenv()["MODRINTH_API_TOKEN"])
    projectId.set(prop("modrinth_id"))
    versionName.set("[${lom.minecraftVersion.get()}] $versionS")
    versionType.set(project.versionType.modrinthName)
    changelog.set(project.changelog)
    uploadFile.set(tasks.remapJar.get())
    gameVersions.add(lom.minecraftVersion.get())
    loaders.add("fabric")
    prop("modrinth_required_dependencies", "")
        .split(", ", ",")
        .filter { it.isNotBlank() }
        .forEach { required.project(it) }
    prop("modrinth_optional_dependencies", "")
        .split(", ", ",")
        .filter { it.isNotBlank() }
        .forEach { optional.project(it) }
    if (readmeFile.exists()) {
        syncBodyFrom.set(
            """${readmeFile.readText()}

[![Contact](https://img.shields.io/badge/-Contact-informational)](https://jfronny.gitlab.io/contact.html)"""
        )
    }
}

tasks.deployRelease.dependsOn(tasks.modrinth)
if (readmeFile.exists()) {
    tasks.deployRelease.dependsOn(tasks.modrinthSyncBody)
}