import io.gitlab.jfronny.convention.ext.*
import io.gitlab.jfronny.jfmod.ext.*
import io.gitlab.jfronny.lom.ext.*

plugins {
    id("jfmod")
    id("com.matthewprenger.cursegradle")
}

curseforge {
    if (System.getenv().containsKey("CURSEFORGE_API_TOKEN")) apiKey = System.getenv()["CURSEFORGE_API_TOKEN"]
    else println("No CURSEFORGE_API_TOKEN specified")
    project {
        id = prop("curseforge_id")
        releaseType = versionType.curseforgeName
        addGameVersion("Fabric")
        addGameVersion(lom.minecraftVersion.get())
        changelog = project.changelog
        mainArtifact(tasks.remapJar.get().archiveFile.get())
        mainArtifact.displayName = "[${lom.minecraftVersion.get()}] $versionS"
        relations {
            prop("curseforge_required_dependencies", "")
                .split(", ", ",")
                .filter { it.isNotBlank() }
                .forEach { requiredDependency(it) }
            prop("curseforge_optional_dependencies", "")
                .split(", ", ",")
                .filter { it.isNotBlank() }
                .forEach { optionalDependency(it) }
        }
        afterEvaluate {
            uploadTask.dependsOn(tasks.build)
        }
    }
    options {
        forgeGradleIntegration = false
    }
}

tasks.deployRelease.dependsOn(tasks.curseforge)