import io.gitlab.jfronny.scripts.*

plugins {
    id("jfmod")
    id("com.matthewprenger.cursegradle")
}

val args = extensions.getByName("jfMod") as JfModExtension

curseforge {
    if (System.getenv().containsKey("CURSEFORGE_API_TOKEN")) apiKey = System.getenv()["CURSEFORGE_API_TOKEN"]
    else println("No CURSEFORGE_API_TOKEN specified")
    project {
        id = args.curseforge.projectId.get()
        releaseType = versionType.curseforgeName
        addGameVersion("Fabric")
        addGameVersion(lom.minecraftVersion.get())
        changelog = project.changelog
        mainArtifact(tasks.remapJar.get()) {
            displayName = "[${lom.minecraftVersion.get()}] $versionS"
        }
        relations {
            args.curseforge.requiredDependencies.getOrElse(listOf()).forEach { requiredDependency(it) }
            args.curseforge.optionalDependencies.getOrElse(listOf()).forEach { optionalDependency(it) }
        }
    }
    options {
        forgeGradleIntegration = false
    }
}

tasks.deployRelease.dependsOn(tasks.curseforge)