plugins {
    id 'fabric-loom' version '0.5.42'
    id 'maven-publish'
    id "com.modrinth.minotaur" version "1.1.0"
    id "com.matthewprenger.cursegradle" version "1.4.0"
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
    maven { url = 'https://server.bbkr.space/artifactory/libs-release'; name = "Cotton" }
    maven { url = "https://maven.dblsaiko.net/"; name = "dblsaiko" }
    maven { url = "https://minecraft.curseforge.com/api/maven"; name = "CurseForge" }
    maven { url = 'https://maven.terraformersmc.com/'; name = "ModMenu" }
    maven { url = "https://maven.shedaniel.me/"; name = "Cloth" }
}

dependencies {
    //to change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API. This is technically optional, but you probably want it anyway.
    modImplementation "net.fabricmc.fabric-api:fabric-api:0.32.5+1.16"

    // PSA: Some older mods, compiled on Loom 0.2.1, might have outdated Maven POMs.
    // You may need to force-disable transitiveness on them.
    modCompile("com.terraformersmc:modmenu:1.16.8")

    include modApi("me.shedaniel.cloth:cloth-config-fabric:4.+")

    modApi "io.github.cottonmc:LibCD:3.0.3+1.16.3"
    modCompile "grondag:frex-mc116:+"
    modCompile("grondag:canvas-mc116:+") {
        exclude(group: "io.github.prospector")
        exclude(group: "me.shedaniel.cloth")
    }
}

processResources {
    inputs.property "version", project.version

    from(sourceSets.main.resources.srcDirs) {
        include "fabric.mod.json"
        expand "version": project.version
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude "fabric.mod.json"
    }
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = "sources"
    from sourceSets.main.allSource
}

jar {
    from "LICENSE"
}

import com.modrinth.minotaur.TaskModrinthUpload

task publishModrinth (type: TaskModrinthUpload){
    token = System.getenv("MODRINTH_API_TOKEN")
    projectId = 'TiF5QWZY'
    versionNumber = "${project.mod_version}"
    uploadFile = remapJar
    addGameVersion("${project.minecraft_version}")
    addLoader('fabric')
    versionName = "[${project.minecraft_version}] ${project.mod_version}"
    afterEvaluate {
        tasks.publishModrinth.dependsOn(remapJar)
        tasks.publishModrinth.dependsOn(sourcesJar)
    }
}

curseforge {
    apiKey = System.getenv("CURSEFORGE_API_TOKEN") == null ? "###" : System.getenv("CURSEFORGE_API_TOKEN")
    project {
        id = "430090"
        releaseType = 'release'
        addGameVersion "Fabric"
        addGameVersion "${project.minecraft_version}"
        changelog = ""
        mainArtifact(file("${project.buildDir}/libs/${archivesBaseName}-${version}.jar"))
        mainArtifact.displayName = "[${project.minecraft_version}] ${project.mod_version}"
        afterEvaluate {
            uploadTask.dependsOn(remapJar)
        }
    }
    options {
        forgeGradleIntegration = false
    }
}