plugins {
    id("jfmod") version "1.6-SNAPSHOT"
}

allprojects { group = "io.gitlab.jfronny" }
base.archivesName = "respackopts"

loom {
    accessWidenerPath.set(file("src/main/resources/respackopts.accesswidener"))
}

repositories {
    maven("https://maven.vram.io/") {
        name = "FREX/Canvas"
        content {
            includeGroup("io.vram")
        }
    }
    maven("https://api.modrinth.com/maven") {
        name = "Modrinth"
        content {
            includeGroup("maven.modrinth")
        }
    }
}

val muscriptVersion = "1.7-SNAPSHOT"
val modmenuVersion = "10.0.0-beta.1"
jfMod {
    minecraftVersion = "1.20.6"
    yarn("build.1")
    loaderVersion = "0.15.10"
    libJfVersion = "3.15.2"
    fabricApiVersion = "0.97.8+1.20.6"

    modrinth {
        projectId = "respackopts"
        requiredDependencies.addAll("fabric-api", "libjf")
        optionalDependencies.add("modmenu")
    }
    curseforge {
        projectId = "430090"
        requiredDependencies.addAll("fabric-api", "libjf")
        optionalDependencies.add("modmenu")
    }
}

dependencies {
    modImplementation("net.fabricmc.fabric-api:fabric-api")
    include(modImplementation("io.gitlab.jfronny:muscript-all:$muscriptVersion")!!)
    modImplementation("io.gitlab.jfronny:muscript-json:$muscriptVersion") {
        isTransitive = false
    }
    include("io.gitlab.jfronny:muscript-json:$muscriptVersion")
    modImplementation("io.gitlab.jfronny.libjf:libjf-data-manipulation-v0")
    modImplementation("io.gitlab.jfronny.libjf:libjf-config-core-v2")
    modImplementation("io.gitlab.jfronny.libjf:libjf-config-ui-tiny")

    val nofabric: Action<ExternalModuleDependency> = Action {
        exclude("net.fabricmc") // required to work around duplicate fabric loaders
    }
    modLocalRuntime("io.gitlab.jfronny.libjf:libjf-devutil", nofabric)
    modLocalRuntime("com.terraformersmc:modmenu:$modmenuVersion", nofabric)
    modClientCompileOnly("com.terraformersmc:modmenu:$modmenuVersion", nofabric)

    modClientCompileOnly("io.vram:frex-fabric:20.2.+")

    testImplementation("org.junit.jupiter:junit-jupiter:5.9.3")

    compileOnly("io.gitlab.jfronny:commons-serialize-generator-annotations:$muscriptVersion")
    annotationProcessor("io.gitlab.jfronny:commons-serialize-generator:$muscriptVersion")

    // Canvas for FREX testing
    //modClientRuntimeOnly("io.vram:canvas-fabric:20.2.+")

    // Sodium for debugging
    modClientRuntimeOnly("maven.modrinth:sodium:mc1.20.6-0.5.8")
}