Respackopts/build.gradle.kts

plugins {
    id("jfmod") version "1.5-SNAPSHOT"
}

allprojects { group = "io.gitlab.jfronny" }
base.archivesName = "respackopts"

repositories {
    maven("https://maven.vram.io/") {
        name = "FREX/Canvas"
        content {
            includeGroup("io.vram")
        }
    }
    maven("https://notalpha.dev/maven/releases") {
        name = "DashLoader"
        content {
            includeGroup("dev.notalpha")
            includeGroup("dev.quantumfusion")
        }
    }
}

val fabricVersion = "0.87.0+1.20.1"
val muscriptVersion = "1.4-SNAPSHOT"
jfMod {
    minecraftVersion = "1.20.1"
    yarn("build.10")
    loaderVersion = "0.14.22"
    libJfVersion = "3.12.4"

    modrinth {
        projectId = "respackopts"
        requiredDependencies.addAll("fabric-api", "libjf")
        optionalDependencies.add("modmenu")
    }
    curseforge {
        projectId = "430090"
        requiredDependencies.addAll("fabric-api", "libjf")
        optionalDependencies.add("modmenu")
    }
}

dependencies {
    modImplementation("net.fabricmc.fabric-api:fabric-api:$fabricVersion")
    include(modImplementation("io.gitlab.jfronny:muscript:$muscriptVersion")!!)
    modImplementation("io.gitlab.jfronny.libjf:libjf-data-manipulation-v0:${jfMod.libJfVersion.get()}")
    modImplementation("io.gitlab.jfronny.libjf:libjf-config-core-v1:${jfMod.libJfVersion.get()}")
    modImplementation("io.gitlab.jfronny.libjf:libjf-config-ui-tiny-v1:${jfMod.libJfVersion.get()}")

    val nofabric: Action<ExternalModuleDependency> = Action {
        exclude("net.fabricmc") // required to work around duplicate fabric loaders
    }
    modLocalRuntime("io.gitlab.jfronny.libjf:libjf-devutil:${jfMod.libJfVersion.get()}", nofabric)
    modLocalRuntime("com.terraformersmc:modmenu:7.2.1", nofabric)
    modClientCompileOnly("com.terraformersmc:modmenu:7.2.1", nofabric)

    modClientCompileOnly("io.vram:frex-fabric:20.0.+")
    modClientCompileOnly("dev.notalpha:dashloader:5.0.0-beta.1+1.20.0")

    testImplementation("org.junit.jupiter:junit-jupiter:5.9.3")

    // Canvas for FREX testing
//    modClientRuntimeOnly("io.vram:canvas-fabric:20.0.+")

    // DashLoader "compatibility"
//    modClientRuntimeOnly("dev.notalpha:dashloader:5.0.0-beta.1+1.20.0")
}