ModsMod/build.gradle

plugins {
    id 'fabric-loom' version '0.5-SNAPSHOT'
    id 'maven-publish'
    id "com.modrinth.minotaur" version "1.1.0"
    id "com.matthewprenger.cursegradle" version "1.4.0"
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
    maven {url = "https://dl.bintray.com/user11681/maven"}
    maven { url = 'https://jitpack.io' }
    maven { url = 'https://maven.terraformersmc.com/'; name = "ModMenu" }
}

dependencies {
    //to change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API. This is technically optional, but you probably want it anyway.
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    // PSA: Some older mods, compiled on Loom 0.2.1, might have outdated Maven POMs.
    // You may need to force-disable transitiveness on them.

    modCompile "me.sargunvohra.mcmods:autoconfig1u:3.2.0-unstable"
    include "me.sargunvohra.mcmods:autoconfig1u:3.2.0-unstable"
    modApi ("me.shedaniel.cloth:config-2:4.8.3") {
        transitive = false
    }
    include ("me.shedaniel.cloth:config-2:4.8.3") {
        transitive = false
    }

    modCompile "com.terraformersmc:modmenu:1.14.15"
}

processResources {
    inputs.property "version", project.version

    from(sourceSets.main.resources.srcDirs) {
        include "fabric.mod.json"
        expand "version": project.version
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude "fabric.mod.json"
    }
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = "sources"
    from sourceSets.main.allSource
}

jar {
    from "LICENSE"
}

import com.modrinth.minotaur.TaskModrinthUpload

task publishModrinth (type: TaskModrinthUpload){
    token = System.getenv("MODRINTH_API_TOKEN") // Use an environment property!
    projectId = '4GhX11Ed'
    versionNumber = "${project.mod_version}"
    uploadFile = remapJar // This is the java jar task
    addGameVersion("${project.minecraft_version}")
    addLoader('fabric')
    versionName = "[${project.minecraft_version}] ${project.mod_version}"
    afterEvaluate {
        tasks.publishModrinth.dependsOn(remapJar)
        tasks.publishModrinth.dependsOn(sourcesJar)
    }
}

curseforge {
    apiKey = System.getenv("CURSEFORGE_API_TOKEN") == null ? "###" : System.getenv("CURSEFORGE_API_TOKEN")
    project {
        id = "405095"
        releaseType = 'release'
        addGameVersion "Fabric"
        addGameVersion "${project.minecraft_version}"
        changelog = ""
        mainArtifact(file("${project.buildDir}/libs/${archivesBaseName}-${version}.jar"))
        mainArtifact.displayName = "[${project.minecraft_version}] ${project.mod_version}"
        afterEvaluate {
            uploadTask.dependsOn(remapJar)
        }
    }
    options {
        forgeGradleIntegration = false
    }
}