plugins {
    id("jfmod")
}

allprojects { group = "io.gitlab.jfronny.libjf" }
subprojects { version = rootProject.version }

val fabricVersion by extra("0.89.1+1.20.2")
val commonsVersion by extra("1.5-SNAPSHOT")
val gsonCompileVersion by extra("1.4-SNAPSHOT")
val modmenuVersion by extra("8.0.0-beta.2")

val annotationsVersion by extra("24.0.1")
val javapoetVersion by extra("1.13.0")

val baseCommonsModules by extra(listOf("http-client", "io", "logging", "logging-slf4j", "serialize", "serialize-gson"))

jfMod {
    minecraftVersion = "1.20.2"
    yarn("build.1")
    loaderVersion = "0.14.22"

    modrinth {
        projectId = "libjf"
        optionalDependencies.add("fabric-api")
    }
    curseforge {
        projectId = "482600"
        optionalDependencies.add("fabric-api")
    }
}

allprojects {
    if (!rootProject.jfMod.isMod(this)) return@allprojects

    base {
        archivesName = "libjf"
    }

    dependencies {
        modLocalRuntime("com.terraformersmc:modmenu:$modmenuVersion") {
            exclude("net.fabricmc") // required to work around duplicate fabric loaders
        }
        modLocalRuntime(fabricApi.module("fabric-command-api-v2", fabricVersion))
        modLocalRuntime(fabricApi.module("fabric-networking-api-v1", fabricVersion))
        compileOnly("io.gitlab.jfronny:commons:$commonsVersion")
        baseCommonsModules.forEach { compileOnly("io.gitlab.jfronny:commons-$it:$commonsVersion") }
    }
}