import io.gitlab.jfronny.scripts.deployDebug
import io.gitlab.jfronny.scripts.deployRelease
import io.gitlab.jfronny.scripts.versionS

plugins {
    id("jf.maven-publish")
    id("net.neoforged.gradle.userdev") version "7.0.145"
}

base {
    archivesName = "libjf-resource-pack-entry-widgets-forge"
}

java {
    toolchain.languageVersion = JavaLanguageVersion.of(21)
}

dependencies {
    implementation(libs.neoforge)
}

publishing {
    publications {
        create<MavenPublication>("lom") {
            from(components["java"])
        }
    }
}

tasks.publish { dependsOn(tasks.build) }
tasks.deployDebug.dependsOn(tasks.publish)
rootProject.tasks.deployDebug.dependsOn(tasks.deployDebug)
rootProject.tasks.deployRelease.dependsOn(tasks.deployRelease)

tasks.processResources {
    val map = mapOf(
        "version" to project.versionS,
        "minecraft_version" to libs.versions.minecraft.get(),
        "loader_version" to libs.versions.neoforge.get()
    )
    filesMatching("META-INF/neoforge.mods.toml") {
        expand(map)
    }
    inputs.property("version", project.versionS)
}