apply from: "https://gitlab.com/-/snippets/2121059/raw/master/jfbase.gradle"

repositories {
    maven { url = 'https://raw.githubusercontent.com/TerraformersMC/Archive/main/releases/'; name = "ModMenu" }
}

sourceSets {
    testmod {
        compileClasspath += main.compileClasspath + main.output
        runtimeClasspath += main.runtimeClasspath + main.output
    }
}

dependencies {
    //to change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.minecraft_version}+${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    include modImplementation(fabricApi.module("fabric-tag-extensions-v0", "0.37.0+1.17"))
    modImplementation "com.terraformersmc:modmenu:2.0.2"
}

loom {
    runs {
        testmodClient {
            client()
            ideConfigGenerated project.rootProject == project
            name = "Testmod Client"
            source sourceSets.testmod
        }
        testmodServer {
            server()
            ideConfigGenerated project.rootProject == project
            name = "Testmod Server"
            source sourceSets.testmod
        }
    }
}