plugins {
    id("jfmod")
}

allprojects {
    group = "io.gitlab.jfronny.libjf"
}

val fabricVersion by extra("0.87.1+1.20.2")
val commonsVersion by extra("1.4-SNAPSHOT")
val gsonCompileVersion by extra("1.3-SNAPSHOT")
val modmenuVersion by extra("7.2.1")

val annotationsVersion by extra("24.0.1")
val javapoetVersion by extra("1.13.0")

jfMod {
    minecraftVersion = "23w33a"
    yarn("build.3")
    loaderVersion = "0.14.22"

    modrinth {
        projectId = "libjf"
        optionalDependencies.add("fabric-api")
    }
    curseforge {
        projectId = "482600"
        optionalDependencies.add("fabric-api")
    }
}

allprojects {
    if (!rootProject.jfMod.isMod(this)) return@allprojects

    base {
        archivesName = "libjf"
    }

    dependencies {
        // Temporarily disabled since modmenu doesn't support snapshots
//        modLocalRuntime("com.terraformersmc:modmenu:$modmenuVersion") {
//            exclude("net.fabricmc") // required to work around duplicate fabric loaders
//        }
        modLocalRuntime(fabricApi.module("fabric-command-api-v2", fabricVersion))
        compileOnly("io.gitlab.jfronny:commons:$commonsVersion")
        compileOnly("io.gitlab.jfronny:commons-gson:$commonsVersion")

        // temporary workaround for snapshot versions since these were previously provided by modmenu. Remove once out of use!
        modLocalRuntime(fabricApi.module("fabric-resource-loader-v0", fabricVersion))
        modLocalRuntime(fabricApi.module("fabric-lifecycle-events-v1", fabricVersion))
        modLocalRuntime(fabricApi.module("fabric-screen-api-v1", fabricVersion))
        modLocalRuntime(fabricApi.module("fabric-key-binding-api-v1", fabricVersion))
    }
}