plugins {
    id 'java-gradle-plugin'
    id 'maven-publish'
}

group project.maven_group
version rootProject.ext.currentVer

repositories {
    mavenCentral()
    maven {
        name = 'JF Commons'
        url = 'https://gitlab.com/api/v4/projects/35745143/packages/maven'
    }
}

dependencies {
    compileOnly(gradleApi())
    implementation("org.apache.ant:ant:$rootProject.ant_version")
    implementation("io.gitlab.jfronny:commons-gson:$rootProject.commons_version")
    implementation("org.ow2.asm:asm:$rootProject.asm_version")
    implementation("org.ow2.asm:asm-commons:$rootProject.asm_version")
    implementation(project(":libjf-config-core-v1")) {
        transitive(false)
    }
}

gradlePlugin {
    plugins {
        simplePlugin {
            id = "io.gitlab.jfronny.libjf.libjf-config-compiler-plugin"
            implementationClass = "io.gitlab.jfronny.libjf.config.plugin.ConfigPlugin"
        }
    }
}

publishing {
    repositories {
        mavenLocal()

        if (project.hasProperty("maven")) {
            maven {
                url = project.getProperty("maven")
                name = "dynamic"

                credentials(HttpHeaderCredentials) {
                    name = "Job-Token"
                    value = System.getenv().CI_JOB_TOKEN
                }
                authentication {
                    header(HttpHeaderAuthentication)
                }
            }
        }
    }
}

tasks.publish.dependsOn(tasks.build)
rootProject.tasks.deployDebug.dependsOn(tasks.publish)

java.nio.file.Files.writeString(java.nio.file.Path.of("$projectDir/src/main/java/io/gitlab/jfronny/libjf/config/plugin/BuildMetadata.java"), """
package io.gitlab.jfronny.libjf.config.plugin;

public class BuildMetadata {
    public static final boolean isRelease = ${project.hasProperty("release")};
}
""")