import io.gitlab.jfronny.scripts.*

plugins {
    id("inceptum.library-conventions")
    id("jf.codegen")
}

dependencies {
    api("io.gitlab.jfronny:commons:${rootProject.extra["jfCommonsVersion"]}")
    api("io.gitlab.jfronny:commons-gson:${rootProject.extra["jfCommonsVersion"]}")
}

val javaVersion by extra(project.java.targetCompatibility)

sourceSets {
    main {
        generate(project) {
            `class`("io.gitlab.jfronny.inceptum.common", "BuildMetadata") {
                val modifiers = "public static final"
                import("io.gitlab.jfronny.commons.ComparableVersion")

                fieldRaw("VERSION", "ComparableVersion", "new ComparableVersion(\"$version\")", modifiers)
                field("IS_PUBLIC", rootProject.extra["isPublic"] as Boolean, modifiers)
                field("IS_RELEASE", rootProject.extra["isRelease"] as Boolean, modifiers)
                field("VM_VERSION", javaVersion.majorVersion.toInt(), modifiers)
                field("WRAPPER_VERSION", rootProject.extra["wrapperVersion"] as Int, modifiers)
            }
        }
    }
}