plugins {
    id("inceptum.application-conventions")
}

group = "io.gitlab.jfronny.inceptum"
version = "0.2.0-1662303777"

dependencies {
    val flavor: String by rootProject.extra
    val lwjglVersion: String by rootProject.extra
    val imguiVersion: String by rootProject.extra

    implementation(project(":launcher"))

    implementation(platform("org.lwjgl:lwjgl-bom:$lwjglVersion"))

    arrayOf("", "-opengl", "-glfw", "-tinyfd").forEach {
        implementation("org.lwjgl:lwjgl$it:$lwjglVersion")
        if (flavor == "windows" || flavor == "fat") implementation("org.lwjgl:lwjgl$it::natives-windows")
        if (flavor == "linux" || flavor == "fat") implementation("org.lwjgl:lwjgl$it::natives-linux")
        if (flavor == "macos" || flavor == "fat") implementation("org.lwjgl:lwjgl$it::natives-macos")
    }

    implementation("io.github.spair:imgui-java-binding:$imguiVersion") // https://github.com/SpaiR/imgui-java
    implementation("io.github.spair:imgui-java-lwjgl3:$imguiVersion")

    if (flavor == "windows" || flavor == "fat") implementation("io.github.spair:imgui-java-natives-windows:$imguiVersion")
    if (flavor == "linux" || flavor == "fat") implementation("io.github.spair:imgui-java-natives-linux:$imguiVersion")
    if (flavor == "macos" || flavor == "fat") implementation("io.github.spair:imgui-java-natives-macos:$imguiVersion")
}

projectDir.resolve("src/main/java/io/gitlab/jfronny/inceptum/imgui/ImBuildMetadata.java").writeText(
    """
    package io.gitlab.jfronny.inceptum.imgui;
    
    public class ImBuildMetadata {
        public static final String FLAVOR = "${rootProject.extra["flavorProp"]}";
    }
""".trimIndent())