plugins {
    id("inceptum.application")
    id("inceptum.manifold")
}

application {
    mainClass.set("io.gitlab.jfronny.inceptum.imgui.GuiMain")
}

dependencies {
    val flavor: String by rootProject.extra
    val lwjglVersion: String by rootProject.extra
    val imguiVersion: String by rootProject.extra

    fun native(name: String) {
        if (flavor == "windows" || flavor == "fat") implementation(name.replace("@platform", "windows"))
        if (flavor == "linux" || flavor == "fat") implementation(name.replace("@platform", "linux"))
        if (flavor == "macos" || flavor == "fat") implementation(name.replace("@platform", "macos"))
    }

    implementation(project(":launcher"))

    arrayOf("", "-opengl", "-glfw", "-tinyfd").forEach {
        implementation("org.lwjgl:lwjgl$it:$lwjglVersion")
        native("org.lwjgl:lwjgl$it:$lwjglVersion:natives-@platform")
    }

    implementation("io.github.spair:imgui-java-binding:$imguiVersion") // https://github.com/SpaiR/imgui-java
    implementation("io.github.spair:imgui-java-lwjgl3:$imguiVersion")
    native("io.github.spair:imgui-java-natives-@platform:$imguiVersion")
}